JUnit 5 Gradle Dependency [build.gradle] Example

Learn to configure junit 5 with gradle, its different modules and how to use them to create and execute tests.

JUnit 5 Gradle Dependency

To run JUnit 5 tests through gradle, you will need minimum two dependencies.

1. JUnit Jupiter Engine Dependency

   JUnit jupiter is required to have two dependencies i.e. junit-jupiter-api and junit-jupiter-engine. junit-jupiter-api has junit annotations (e.g. @Test) to write tests and extensions and junit-jupiter-engine has test engine implementation which is required at runtime to execute the tests.

   Internally, junit-jupiter-engine is dependent on junit-jupiter-api, so adding junit-jupiter-engine only brings both dependencies into classpath.

   You can learn about internal dependencies between various junit jars in this image.

   dependencies {
   	testRuntime("org.junit.jupiter:junit-jupiter-engine:5.0.0-M4")
   }
   

2. JUnit Platform Runner Dependency

   You will need junit-platform-runner for executing tests and test suites on the JUnit Platform in a JUnit 4 environment.

   Internally, junit-platform-runner is dependent on junit-platform-suite-api and junit-platform-launcher, so adding junit-jupiter-engine only brings all three dependencies into classpath.

   dependencies {
   	testRuntime("org.junit.platform:junit-platform-runner:1.0.0-M4")
   }
   

Execute JUnit 4 Tests with JUnit 5

To execute junit 4 tests in junit 5 environment, you will need to include junit-vintage-engine dependency. JUnit Vintage provides a TestEngine for running JUnit 3 and JUnit 4 based tests on the platform.

dependencies {
    //To run JUnit 3 and junit 4 tests
    testCompile("junit:junit:4.12")
    testRuntime("org.junit.vintage:junit-vintage-engine:4.12.0-M4")
}

By configuring above in build.gradle, now you can run your old junit 3 or junit 4 tests with junit 5.

JUnit 5 Gradle Example

A sample build.gradle file for running tests built with junit 5 is as follow:

buildscript {
	repositories {
		mavenCentral()
	}
	dependencies {
		classpath 'org.junit.platform:junit-platform-gradle-plugin:1.0.0-M4'
	}
}

repositories {
	mavenCentral()
}

ext.junit4Version        = '4.12'
ext.junitVintageVersion  = '4.12.0-M4'
ext.junitPlatformVersion = '1.0.0-M4'
ext.junitJupiterVersion  = '5.0.0-M4'
ext.log4jVersion         = '2.6.2'

apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'idea'
apply plugin: 'org.junit.platform.gradle.plugin'

jar {
	baseName = 'junit5-gradle-consumer'
	version = '1.0.0-SNAPSHOT'
}

compileTestJava {
	sourceCompatibility = 1.8
	targetCompatibility = 1.8
	options.compilerArgs += '-parameters'
}

junitPlatform {
	// platformVersion '1.0.0-M4'
	filters {
		engines {
			// include 'junit-jupiter', 'junit-vintage'
			// exclude 'custom-engine'
		}
		tags {
			// include 'fast'
			exclude 'slow'
		}
		// includeClassNamePattern '.*Test'
	}
	// enableStandardTestTask true
	// reportsDir file('build/test-results/junit-platform') // this is the default
	logManager 'org.apache.logging.log4j.jul.LogManager'
}

dependencies {
	// JUnit Jupiter API and TestEngine implementation
	testCompile("org.junit.jupiter:junit-jupiter-api:${junitJupiterVersion}")
	testRuntime("org.junit.jupiter:junit-jupiter-engine:${junitJupiterVersion}")

	// If you also want to support JUnit 3 and JUnit 4 tests
	testCompile("junit:junit:${junit4Version}")
	testRuntime("org.junit.vintage:junit-vintage-engine:${junitVintageVersion}")

	testRuntime("org.apache.logging.log4j:log4j-core:${log4jVersion}")
	testRuntime("org.apache.logging.log4j:log4j-jul:${log4jVersion}")
}

task wrapper(type: Wrapper) {
	description = 'Generates gradlew[.bat] scripts'
	gradleVersion = '3.0'
}

Ref : Git

Drop me your questions in comments section.

Happy Learning !!